#37630

Committed 23 Sep 2023 06:01PM UTC coverage: 85.958% (-0.5%) from 86.504%

Build # #37630

Build Type

push

local

Committed by

web-flow

Commit Message

Fix error in comment [NFC] (#51181)

Run Details

72248 of 84050 relevant lines covered (85.96%)

11837257.3 hits per line

Source File
Press 'n' to go to next uncovered line, 'b' for previous

82.35

/stdlib/Markdown/src/parse/parse.jl

# This file is a part of Julia. License is MIT: https://julialang.org/license

mutable struct MD
    content::Vector{Any}
    meta::Dict{Symbol, Any}

    MD(content::AbstractVector, meta::Dict = Dict()) =
        new(content, meta)
end

MD(xs...) = MD(vcat(xs...))

function MD(cfg::Config, xs...)
    md = MD(xs...)
    md.meta[:config] = cfg
    return md
end

config(md::MD) = md.meta[:config]::Config

# Forward some array methods

Base.push!(md::MD, x) = push!(md.content, x)
Base.getindex(md::MD, args...) = md.content[args...]
Base.setindex!(md::MD, args...) = setindex!(md.content, args...)
Base.lastindex(md::MD) = lastindex(md.content)
Base.firstindex(md::MD) = firstindex(md.content)
Base.length(md::MD) = length(md.content)
Base.isempty(md::MD) = isempty(md.content)
Base.copy(md::MD) = MD(copy(md.content), copy(md.meta))

==(a::MD, b::MD) = (html(a) == html(b))

# Parser functions:
#   md – should be modified appropriately
#   return – basically, true if parse was successful
#     false uses the next parser in the queue, true
#     goes back to the beginning
#
# Inner parsers:
#   return – element to use or nothing

# Inner parsing

function parseinline(stream::IO, md::MD, parsers::Vector{Function})
    for parser in parsers
        inner = parser(stream, md)
        inner ≡ nothing || return inner
    end
end

function parseinline(stream::IO, md::MD, config::Config)
    content = []
    buffer = IOBuffer()
    while !eof(stream)
        char = peek(stream, Char)
        if haskey(config.inner, char) &&
                (inner = parseinline(stream, md, config.inner[char])) !== nothing
            c = String(take!(buffer))
            !isempty(c) && push!(content, c)
            buffer = IOBuffer()
            push!(content, inner)
        else
            write(buffer, read(stream, Char))
        end
    end
    c = String(take!(buffer))
    !isempty(c) && push!(content, c)
    return content
end

parseinline(s::AbstractString, md::MD, c::Config) =
    parseinline(IOBuffer(s), md, c)

parseinline(s, md::MD) = parseinline(s, md, config(md))

# Block parsing

function parse(stream::IO, block::MD, config::Config; breaking = false)
    skipblank(stream)
    eof(stream) && return false
    for parser in (breaking ? config.breaking : [config.breaking; config.regular])
        parser(stream, block) && return true
    end
    return false
end

parse(stream::IO, block::MD; breaking = false) =
  parse(stream, block, config(block), breaking = breaking)

function parse(stream::IO; flavor = julia)
    isa(flavor, Symbol) && (flavor = flavors[flavor])
    markdown = MD(flavor)
    while parse(stream, markdown, flavor) end
    return markdown
end

1	# This file is a part of Julia. License is MIT: https://julialang.org/license
2
3	mutable struct MD
4	content::Vector{Any}
5	meta::Dict{Symbol, Any}
6
7	MD(content::AbstractVector, meta::Dict = Dict()) =	14,207✔
8	new(content, meta)
9	end
10
11	MD(xs...) = MD(vcat(xs...))	4,236✔
12
13	function MD(cfg::Config, xs...)	×
14	md = MD(xs...)	4,152✔
15	md.meta[:config] = cfg	4,152✔
16	return md	4,152✔
17	end
18
19	config(md::MD) = md.meta[:config]::Config	18,051✔
20
21	# Forward some array methods
22
23	Base.push!(md::MD, x) = push!(md.content, x)	11,052✔
24	Base.getindex(md::MD, args...) = md.content[args...]	×
25	Base.setindex!(md::MD, args...) = setindex!(md.content, args...)	×
26	Base.lastindex(md::MD) = lastindex(md.content)	×
27	Base.firstindex(md::MD) = firstindex(md.content)	×
28	Base.length(md::MD) = length(md.content)	×
29	Base.isempty(md::MD) = isempty(md.content)	×
30	Base.copy(md::MD) = MD(copy(md.content), copy(md.meta))	×
31
32	==(a::MD, b::MD) = (html(a) == html(b))	5✔
33
34	# Parser functions:
35	# md – should be modified appropriately
36	# return – basically, true if parse was successful
37	# false uses the next parser in the queue, true
38	# goes back to the beginning
39	#
40	# Inner parsers:
41	# return – element to use or nothing
42
43	# Inner parsing
44
45	function parseinline(stream::IO, md::MD, parsers::Vector{Function})	20,423✔
46	for parser in parsers	20,423✔
47	inner = parser(stream, md)	23,419✔
48	inner ≡ nothing \|\| return inner	42,225✔
49	end	4,613✔
50	end
51
52	function parseinline(stream::IO, md::MD, config::Config)	10,570✔
53	content = []	10,570✔
54	buffer = IOBuffer()	10,570✔
55	while !eof(stream)	730,144✔
56	char = peek(stream, Char)	719,574✔
57	if haskey(config.inner, char) &&	719,574✔
58	(inner = parseinline(stream, md, config.inner[char])) !== nothing
59	c = String(take!(buffer))	18,806✔
60	!isempty(c) && push!(content, c)	18,806✔
61	buffer = IOBuffer()	18,806✔
62	push!(content, inner)	18,806✔
63	else
64	write(buffer, read(stream, Char))	700,768✔
65	end
66	end	719,574✔
67	c = String(take!(buffer))	10,570✔
68	!isempty(c) && push!(content, c)	10,570✔
69	return content	10,570✔
70	end
71
72	parseinline(s::AbstractString, md::MD, c::Config) =	3,141✔
73	parseinline(IOBuffer(s), md, c)
74
75	parseinline(s, md::MD) = parseinline(s, md, config(md))	10,570✔
76
77	# Block parsing
78
79	function parse(stream::IO, block::MD, config::Config; breaking = false)	46,376✔
80	skipblank(stream)	23,188✔
81	eof(stream) && return false	23,188✔
82	for parser in (breaking ? config.breaking : [config.breaking; config.regular])	19,036✔
83	parser(stream, block) && return true	145,879✔
84	end	140,437✔
85	return false	6,797✔
86	end
87
88	parse(stream::IO, block::MD; breaking = false) =	13,938✔
89	parse(stream, block, config(block), breaking = breaking)
90
91	function parse(stream::IO; flavor = julia)	8,304✔
92	isa(flavor, Symbol) && (flavor = flavors[flavor])	×
93	markdown = MD(flavor)	4,152✔
94	while parse(stream, markdown, flavor) end	28,286✔
95	return markdown	4,152✔
96	end

JuliaLang / julia / #37630

Source File Press 'n' to go to next uncovered line, 'b' for previous

Source File
Press 'n' to go to next uncovered line, 'b' for previous