moosetechnology / GitProjectHealth / 11142394560

BitBucketApi >> activitiesOfPullRequest: pullRequestId inRepo: repositorySlug ofProject: projectKey [

        ^ self allValuesOfPath:

                  self basePath , '/projects/' , projectKey , '/repos/'

                  , repositorySlug , '/pull-requests/' , pullRequestId printString

                  , '/activities'

]

BitBucketApi >> allValuesOfPath: path [

        | results values |

        self prepareZnClient.

        self client path: path.

        values := OrderedCollection new.

        [

        results := self client get.

        results := (NeoJSONReader on: results readStream) next.

        values addAll: (results at: #values).

        results

                at: #nextPageStart

                ifPresent: [

                client queryAt: #start put: (results at: #nextPageStart) ].

        results at: #isLastPage ] whileFalse.

        ^ values

]

BitBucketApi >> apiToken [

        ^ apiToken

]

BitBucketApi >> apiToken: anObject [

        apiToken := anObject

]

BitBucketApi >> basePath [

        ^ basePath

]

BitBucketApi >> basePath: anObject [

        basePath := anObject

]

BitBucketApi >> bearerToken [

        ^ bearerToken

]

BitBucketApi >> bearerToken: anObject [

        bearerToken := anObject

]

BitBucketApi >> client [

        ^ client

]

BitBucketApi >> client: anObject [

        client := anObject

]

BitBucketApi >> commitsOfPullRequest: pullRequestId ofRepo: repoSlug inProject: projectKey [

        ^ self allValuesOfPath: self basePath, '/projects/', projectKey, '/repos/', repoSlug, '/pull-requests/', pullRequestId printString, '/commits'.

]

BitBucketApi >> commitsOfRepo: repositorySlug inProject: projectKey since: since until: until [

        "/rest/api/1.0/projects/{projectKey}/repos/{repositorySlug}/commits"

        | results lastDate lastCommitterTimestamp commits |

        self prepareZnClient.

        self client path:

                self basePath , '/projects/' , projectKey , '/repos/'

                , repositorySlug , '/commits'.

        self client queryAt: 'merges' put: 'exclude'.

        commits := OrderedCollection new.

        [

        results := self client get.

        results := (NeoJSONReader on: results readStream) next.

        commits addAll: (results at: #values).

        results

                at: #nextPageStart

                ifPresent: [

                client queryAt: #start put: (results at: #nextPageStart) ].

        (results at: #isLastPage)

                ifTrue: [ false ]

                ifFalse: [

                        lastCommitterTimestamp := commits last at: #authorTimestamp.

                        lastDate := DateAndTime fromUnixTime: lastCommitterTimestamp / 1000.

                        since asDate <= lastDate ] ] whileTrue.

        ^ commits select: [ :commit |

                  | commitDate |

                  commitDate := DateAndTime fromUnixTime:

                                        (commit at: #authorTimestamp) / 1000.

                  commitDate >= since asDateAndTime and:

                          commitDate <= until asDateAndTime ]

]

BitBucketApi >> diffsOfCommit: commitID inRepo: repositorySlug inProject: projectKey [

        | results |

        self prepareZnClient.

        self client path:

                self basePath , '/projects/' , projectKey , '/repos/'

                , repositorySlug , '/commits/' , commitID , '/diff'.

        results := self client get.

        ^ (NeoJSONReader on: results readStream) next

]

BitBucketApi >> endpoint [

        ^ endpoint

]

BitBucketApi >> endpoint: anObject [

        endpoint := anObject

]

BitBucketApi >> initialize [

        self client: (ZnClient new

                         accept: ZnMimeType applicationJson;

                         yourself).

        self basePath: 'rest/api/1.0'

]

BitBucketApi >> prepareZnClient [

        client := ZnClient new

                          accept: ZnMimeType applicationJson;

                          yourself.

        client host: self endpoint.

        client http.

        self bearerToken ifNotNil: [ :token |

                client headerAt: #Authorization put: 'Bearer ' , token ].

        self apiToken ifNotNil: [ :anApiKey |

                client headerAt: #Authorization put: 'Basic '

                        , (self username , ':' , self apiToken) utf8Encoded base64Encoded ].

]

BitBucketApi >> projects [

        "/rest/api/1.0/projects"

        ^ self allValuesOfPath: self basePath , '/projects'.

]

BitBucketApi >> pullRequestsOfRepo: repositorySlug inProject: projectKey since: since until: until [

        | pullRequests results lastCommitterTimestamp lastDate |

        self prepareZnClient.

        self client path:

                self basePath , '/projects/' , projectKey , '/repos/'

                , repositorySlug , '/pull-requests'.

        self client queryAt: 'state' put: 'all'.

        pullRequests := OrderedCollection new.

        [

        results := self client get.

        results := (NeoJSONReader on: results readStream) next.

        pullRequests addAll: (results at: #values).

        results

                at: #nextPageStart

                ifPresent: [

                client queryAt: #start put: (results at: #nextPageStart) ].

        (results at: #isLastPage)

                ifTrue: [ false ]

                ifFalse: [

                        lastCommitterTimestamp := pullRequests last at: #createdDate.

                        lastDate := DateAndTime fromUnixTime: lastCommitterTimestamp / 1000.

                        since asDate <= lastDate ] ] whileTrue.

        ^ pullRequests select: [ :commit |

                  | commitDate |

                  commitDate := DateAndTime fromUnixTime:

                                        (commit at: #createdDate) / 1000.

                  commitDate >= since asDate and: commitDate <= until asDate ]

]

BitBucketApi >> repositoriesOfProject: projectKey [

        ^self allValuesOfPath: self basePath, '/projects/', projectKey, '/repos'.

]

BitBucketApi >> user: accountId [

        "https://developer.atlassian.com/cloud/bitbucket/rest/api-group-users/#api-user-get"

        self prepareZnClient.

        self client path: self basePath, '/user/' , accountId printString.

        ^ self client get

]

BitBucketApi >> username [

        ^ username

]

BitBucketApi >> username: anObject [

        username := anObject

]

BitBucketApi >> usersByUsername: usernameString [

        | users |

        self prepareZnClient.

        self client path: self basePath , '/admin/users'.

        self client queryAt: 'filter' put: usernameString.

        users := self client get.

        users := (NeoJSONReader on: users readStream) next.

        ^ (users at: #values)

]