moosetechnology / GitProjectHealth / 10880677211

GLHUserCatalogueV2 class >> loadFromJson: aString [

        | catalogue dic |

        catalogue := self new.

        dic := (STONJSON fromString: aString) asDictionary.

        dic associationsDo: [ :assoc |

                | itsName itsUsername itsCommitNames itsId itsProjectIDs|

                itsName := assoc key.

                itsCommitNames := assoc value at: #foundNames.

                itsUsername := assoc value at: #username.

                itsId := assoc value at: #id.

                itsProjectIDs := assoc value at: #contributedProjects ifAbsent: [{}].

                catalogue

                        addUser: (GLHUser new

                                         id: itsId;

                                         username: itsUsername;

                                         name: itsName;

                                         yourself)

                        withNames: itsCommitNames

                        withProjects: itsProjectIDs ].

        ^ catalogue

]

GLHUserCatalogueV2 class >> scrapeContributedProjectsForCommitAuthorsRelatedToUser: aGLHUser [

        "get all "

        | maxProjects itsProjects |

        self

                deprecated:

                'Use #scrapeWithImporter:ContributedProjectsForCommitAuthorsRelatedToUser: instead'

                on: '12 August 2024'

                in:

                'Pharo-11.0.0+build.726.sha.aece1b5473acf3830a0e082c1bc3a15d4ff3522b (64 Bit)'.

        aGLHUser id ifNil: [ ^ {  } asSet ].

        maxProjects := 10.

        GLHModelImporter current withCommitDiffs: false.

        itsProjects := aGLHUser contributedProjects ifEmpty: [

                               GLHModelImporter current

                                       importContributedProjectsOfUser: aGLHUser ].

        itsProjects

                collect: [ :project |

                        GLHModelImporter current importAndLoadLatestsCommitsOfProject:

                                project ]

                from: 1

                to: (itsProjects size min: maxProjects).

        ^ (aGLHUser commits collect: [ :commit | commit author_name ]) asSet

]

GLHUserCatalogueV2 class >> scrapeWithImporter: anImporter contributedProjectsForCommitAuthorsRelatedToUser: aGLHUser [

        "get all "

        | maxProjects itsProjects |

        aGLHUser id ifNil: [ ^ {  } asSet ].

        maxProjects := 10.

        anImporter withCommitDiffs: false.

        itsProjects := aGLHUser contributedProjects ifEmpty: [

                               anImporter

                                       importContributedProjectsOfUser: aGLHUser ].

        itsProjects

                collect: [ :project |

                        anImporter importAndLoadLatestsCommitsOfProject:

                                project ]

                from: 1

                to: (itsProjects size min: maxProjects).

        ^ (aGLHUser commits collect: [ :commit | commit author_name ]) asSet

]

GLHUserCatalogueV2 >> RSHeatMapLevenshtein [

                | builder|

        builder := RSHeatmap new.

        builder objectsX: self keys.

        builder objectsY: self keys.

        builder dataMatrix: self levenshteinMatrix.

        builder build.

        builder gradientLegend remove.

        builder canvas open

]

GLHUserCatalogueV2 >> RSHeatMapLevenshteinTrimedAt: aBlockCondition [

                | builder matrice|

        builder := RSHeatmap new.

        builder objectsX: self keys.

        builder objectsY: self keys.

        matrice := self levenshteinMatrix.

        1 to: matrice size do: [ :i |

                1 to: (matrice at: i) size do: [ :j |

                        |val|

                        val := ((matrice at: i) at: j).

                        (matrice at: i) at: j put: ( aBlockCondition value: val ).

                         ] ].

        builder dataMatrix: matrice.

        builder build.

        builder gradientLegend remove.

        builder canvas open

]

GLHUserCatalogueV2 >> addUser: aGLHUser [

        ^ self at: aGLHUser name ifAbsentPut: [

                self initACatalogueEntryForUser: aGLHUser ]

]

GLHUserCatalogueV2 >> addUser: aGLHUser withName: name [

        ^ self addUser: aGLHUser withNames: { name }

]

GLHUserCatalogueV2 >> addUser: aGLHUser withNames: aCollectionOfNames [

        | entry |

        entry := (self

                at: aGLHUser name

                ifAbsentPut: [ (self initACatalogueEntryForUser: aGLHUser ). ]).

        (entry  at: #names)  addAll: aCollectionOfNames. 

        ^ entry

]

GLHUserCatalogueV2 >> addUser: aGLHUser withNames: aCollectionOfNames withProject: aProjectID [

        ^ self addUser: aGLHUser withNames: aCollectionOfNames withProjects: { aProjectID }

]

GLHUserCatalogueV2 >> addUser: aGLHUser withNames: aCollectionOfNames withProjects: aCollectionOfProjectIDs [

        |entry|

        entry := self addUser: aGLHUser withNames: aCollectionOfNames.

        (entry at: #contributedProjects) addAll: aCollectionOfProjectIDs.

        ^ entry. 

]

GLHUserCatalogueV2 >> addUser: aGLHUser withProject: aProjectID [

        ^ self addUser: aGLHUser withProjects: {aProjectID}.

]

GLHUserCatalogueV2 >> addUser: aGLHUser withProjects: aCollectionOfProjectIDs [

        |entry|

        entry := self addUser: aGLHUser.

        (entry at: #contributedProjects) addAll: aCollectionOfProjectIDs.

        ^ entry.

]

GLHUserCatalogueV2 >> atId: anId [ 

        ^ self detect: [ :entry |

                (entry at: #user) id =  anId ]

]

GLHUserCatalogueV2 >> collectUsernames [

        | username2User |

        self ifEmpty: [ ^ {  } ].

        username2User := OrderedDictionary new.

        self associationsDo: [ :assoc |

                | user |

                user := assoc value at: #user .

                (assoc value at: #names) do: [ :username | username2User at: username put: user ] ].

        ^ username2User

]

GLHUserCatalogueV2 >> completeAuthorNameOfUser: aGLHUser with: authorName [

        self

                deprecated: 'Use #addUser:withName: instead'

                on: '12 August 2024'

                in:

                'Pharo-11.0.0+build.726.sha.aece1b5473acf3830a0e082c1bc3a15d4ff3522b (64 Bit)'.

        self addUser: aGLHUser withName: authorName

]

GLHUserCatalogueV2 >> completeAuthorNameOfUser: aGLHUser withAll: authorNames [

        self

                deprecated: 'Use #addUser:withNames: instead'

                on: '12 August 2024'

                in:

                'Pharo-11.0.0+build.726.sha.aece1b5473acf3830a0e082c1bc3a15d4ff3522b (64 Bit)'.

        self addUser: aGLHUser withNames: authorNames

]

GLHUserCatalogueV2 >> exportToJson [

        | tempDic |

        "        tempDic := self associations collect: [ :assoc |

                                        Dictionary new at: (assoc key name) put: ({

                                   (#names -> assoc value asArray).

                                   (#id -> assoc key id) } asDictionary); yourself ]."

        tempDic := Dictionary new.

        self associationsDo: [ :assoc |

                |entry user names projectIDs|

                entry := assoc value.

                user := entry at: #user.

                names := entry at: #names.

                projectIDs := entry at: #contributedProjects.

                tempDic

                        at: assoc key put: {

                                        (#name -> user name).

                                        (#username -> user username).

                                        (#foundNames -> names asArray).

                                        (#contributedProjects -> projectIDs asArray).

                                        (#id -> user id) } asDictionary;

                        yourself ].

        ^ STONJSON toStringPretty: tempDic

]

GLHUserCatalogueV2 >> fuse: mainUser with: subUser [ 

        self at: mainUser ifPresent: [ :entry |

                self at: subUser ifAbsent: [ ^ self ]. 

                (entry at: #names) addAll: (self at: subUser at: #names ).

                (entry at: #contributedProjects) addAll: (self at: subUser at: #contributedProjects ).

                self removeKey: subUser.

                 ].

]

GLHUserCatalogueV2 >> initACatalogueEntryForUser: aGLHUser [.

^ Dictionary new

                        at: #user put: aGLHUser;

                        at: #names put: (Set new

                                         add: aGLHUser username;

                                         add: aGLHUser name;

                                         yourself);

                        at: #contributedProjects put: (Set new 

                                        addAll: (aGLHUser contributedProjects collect: #id); 

                                        yourself );

                        yourself

]

GLHUserCatalogueV2 >> initialize [

        anImporter := GLHModelImporter new.

]

GLHUserCatalogueV2 >> levenshteinMatrix [ 

        | matrix|

        matrix := Array new: self keys size .

        1 to: matrix size do: [ :i | matrix at: i put: (Array new: self keys size) ]. 

        1 to: self keys size do: [ :i |

                1 to: self keys size do: [ :j |

                        (matrix at: i) at: j put: ( (self keys at: i) absLevenshteinDistanceWith: (self keys at: j) ). 

                          ].

                  ].

        ^ matrix.

]

GLHUserCatalogueV2 >> names [

        ^ self collect: [ :entry | entry at: #names ]

]

GLHUserCatalogueV2 >> namesAt: aGLHUser [

        ^ (self at: aGLHUser name) at: #names.

]

GLHUserCatalogueV2 >> reImportAllUsers [

        "use it after a catalogue import from JSON"

        self associationsDo: [ :assoc |

                | user |

                user := assoc value at: #user.

                user := anImporter

                                ifNotNil: [

                                        user id

                                                ifNotNil: [ anImporter importUser: user id ]

                                                ifNil: [ anImporter importUserByUsername: user username ] ]

                                ifNil: [user].

                assoc value at: #user put: user ]

]

GLHUserCatalogueV2 >> reImportUser: aGLHUser [

        "use it after a catalogue import from JSON"

        |user|

        user := anImporter

                                ifNotNil: [

                                        aGLHUser id

                                                ifNotNil: [ anImporter importUser: aGLHUser id ]

                                                ifNil: [ anImporter importUserByUsername: aGLHUser username ] ]

                                ifNil: [aGLHUser].

        self at: aGLHUser name at: #user put: (user).

]

GLHUserCatalogueV2 >> scrapeAuthorNameForAllRealUsers [

        |listOfUsers|

        listOfUsers := self users select: [ :user | user id isNotNil ].

        listOfUsers do: [ :user | self scrapeAuthorNameForUser: user ].

]

GLHUserCatalogueV2 >> scrapeAuthorNameForAllUsers [

        |listOfUsers|

        listOfUsers := self users. 

        listOfUsers do: [ :user | self scrapeAuthorNameForUser: user ]

]

GLHUserCatalogueV2 >> scrapeAuthorNameForUser: aGLHUser [

        self addUser: aGLHUser withNames: (GLHUserCatalogue

                         scrapeWithImporter: anImporter

                         contributedProjectsForCommitAuthorsRelatedToUser: aGLHUser).

]

GLHUserCatalogueV2 >> scrapeAuthorNamesForUsers: aUserCollection [ 

        aUserCollection do: [ :aGLHUser |

                self scrapeAuthorNameForUser: aGLHUser

                 ].

]

GLHUserCatalogueV2 >> searchId: anId [ 

        ^ self select: [ :entry | (entry at: #user) id = anId ].

]

GLHUserCatalogueV2 >> searchModelForAuthorNamesOfUser: aGLHUser [

        self addUser: aGLHUser withNames: 

                (aGLHUser commits collect: [ :c | c author_name ])

]

GLHUserCatalogueV2 >> searchName: aName [

        ^ self select: [ :entry |

                |collectionOfName|

                collectionOfName := entry at: #names.

                  (' ' join: collectionOfName) asLowercase includesSubstring:

                          aName asLowercase ]

]

GLHUserCatalogueV2 >> searchUserWithName: aName [

        ^ (self searchName: aName) users

]

GLHUserCatalogueV2 >> userAt: aGLHUser [

        ^ (self at: aGLHUser name) at: #user.  

]

GLHUserCatalogueV2 >> users [

        ^ self collect: [ :entry | entry at: #user ].

]

GLHUserCatalogueV2 >> weirdUsers [

        "return user that have name containing weird caracter, making them suspicious"

        ^ self select: [ :entry |

                ((entry at:#user) name includesSubstring: '.') or: [ 

                        (entry at:#user) name includesSubstring: '@' ]

                 ].

]