bf7b407df487178ba9b793a13ed30727a6359fb6

Committed 21 Apr 2024 05:01PM UTC coverage: 61.483% (+0.9%) from 60.579%

Build # bf7b407df487178ba9b793a13ed30727a6359fb6

Build Type

push

github

Committed by

mruoss

Commit Message

chore(deps): update dependency bandit to ~> 1.5.0

Run Details

340 of 553 relevant lines covered (61.48%)

7.34 hits per line

Source File
Press 'n' to go to next uncovered line, 'b' for previous

100.0

/lib/kompost/kompo/postgres/instance.ex

defmodule Kompost.Kompo.Postgres.Instance do
  @moduledoc """
  Provides an interface to Postgrex. `connect/2` starts Postgrex under
  a dynamic supervisor (`Kompost.Kompo.Postgres.ConnectionSupervisor`) and
  register the process at the `Kompost.Kompo.Postgres.ConnectionRegistry`
  """

  alias Kompost.Kompo.Postgres.ConnectionRegistry
  alias Kompost.Kompo.Postgres.ConnectionSupervisor
  alias Kompost.Kompo.Postgres.Privileges

  alias Kompost.Tools.NamespaceAccess

  @typedoc """
  Defines the ID for an instance. The ID used as key when registering the
  Postgrex process at the `Kompost.Kompo.Postgres.ConnectionRegistry`
  """
  @type id :: {namespace :: binary() | :cluster, name :: binary()}

  @doc """
  Checks in the `Kompost.Kompo.Postgres.ConnectionRegistry` for an existing
  connection defined by the given `id`. If no such connection exists, a new
  `Postgrex` process is started, connecting to a Postgres instance defined by
  the `conn_args`. The process is then registered at the
  `Kompost.Kompo.Postgres.ConnectionRegistry`.
  """
  @spec connect(
          id(),
          conn_args :: Keyword.t(),
          allowed_namespaces :: NamespaceAccess.allowed_namespaces()
        ) ::
          {:ok, Postgrex.conn()}
          | {:error, Postgrex.Error.t() | Exception.t()}
          | DynamicSupervisor.on_start_child()
  def connect(id, conn_args, allowed_namespaces) do
    with {:lookup, []} <- {:lookup, lookup(id)},
         {:ok, _} <-
           conn_args
           |> Postgrex.Utils.default_opts()
           |> Postgrex.Protocol.connect() do
      args =
        Keyword.put(
          conn_args,
          :name,
          {:via, Registry,
           {ConnectionRegistry, id,
            Keyword.put(conn_args, :allowed_namespaces, allowed_namespaces)}}
        )

      DynamicSupervisor.start_child(ConnectionSupervisor, {Postgrex, args})
    else
      {:lookup, [{conn, _, _}]} -> {:ok, conn}
      connection_error -> connection_error
    end
  end

  @doc """
  Checks in the `Kompost.Kompo.Postgres.ConnectionRegistry` for an existing
  connection defined by the given `id`.
  """
  @spec lookup(id()) :: [
          {pid, conn_args :: keyword(),
           allowed_namespaces :: NamespaceAccess.allowed_namespaces()}
        ]
  def lookup(id) do
    Registry.lookup(ConnectionRegistry, id)
    |> Enum.map(fn {pid, args} ->
      {allowed_namespaces, conn_args} = Keyword.pop!(args, :allowed_namespaces)
      {pid, conn_args, allowed_namespaces}
    end)
  end

  @doc """
  Checks if the user connected to the given `conn` has all the privileges
  required to work with this `Kompo`.
  """
  @spec check_privileges(conn :: Postgrex.conn()) :: :ok | {:error, binary()}
  def check_privileges(conn) do
    with :ok <- Privileges.check_create_role_privilege(conn) do
      Privileges.check_create_database_privilege(conn)
    end
  end

  @doc """
  Disconnects the connection with the given `id` by stopping the referenced
  `Postgrex` process.
  """
  @spec disconnect(id()) :: :ok
  def disconnect(id) do
    case lookup(id) do
      [{conn, _, _}] ->
        # This will also unregister the process at the ConnectionRegistry:
        DynamicSupervisor.terminate_child(ConnectionSupervisor, conn)
        :ok

      [] ->
        :ok
    end
  end
end

1	defmodule Kompost.Kompo.Postgres.Instance do
2	@moduledoc """
3	Provides an interface to Postgrex. `connect/2` starts Postgrex under
4	a dynamic supervisor (`Kompost.Kompo.Postgres.ConnectionSupervisor`) and
5	register the process at the `Kompost.Kompo.Postgres.ConnectionRegistry`
6	"""
7
8	alias Kompost.Kompo.Postgres.ConnectionRegistry
9	alias Kompost.Kompo.Postgres.ConnectionSupervisor
10	alias Kompost.Kompo.Postgres.Privileges
11
12	alias Kompost.Tools.NamespaceAccess
13
14	@typedoc """
15	Defines the ID for an instance. The ID used as key when registering the
16	Postgrex process at the `Kompost.Kompo.Postgres.ConnectionRegistry`
17	"""
18	@type id :: {namespace :: binary() \| :cluster, name :: binary()}
19
20	@doc """
21	Checks in the `Kompost.Kompo.Postgres.ConnectionRegistry` for an existing
22	connection defined by the given `id`. If no such connection exists, a new
23	`Postgrex` process is started, connecting to a Postgres instance defined by
24	the `conn_args`. The process is then registered at the
25	`Kompost.Kompo.Postgres.ConnectionRegistry`.
26	"""
27	@spec connect(
28	id(),
29	conn_args :: Keyword.t(),
30	allowed_namespaces :: NamespaceAccess.allowed_namespaces()
31	) ::
32	{:ok, Postgrex.conn()}
33	\| {:error, Postgrex.Error.t() \| Exception.t()}
34	\| DynamicSupervisor.on_start_child()
35	def connect(id, conn_args, allowed_namespaces) do
36	with {:lookup, []} <- {:lookup, lookup(id)},	13✔
37	{:ok, _} <-	12✔
38	conn_args
39	\|> Postgrex.Utils.default_opts()
40	\|> Postgrex.Protocol.connect() do
41	args =	11✔
42	Keyword.put(
43	conn_args,
44	:name,
45	{:via, Registry,
46	{ConnectionRegistry, id,
47	Keyword.put(conn_args, :allowed_namespaces, allowed_namespaces)}}
48	)
49
50	DynamicSupervisor.start_child(ConnectionSupervisor, {Postgrex, args})	11✔
51	else
52	{:lookup, [{conn, _, _}]} -> {:ok, conn}
53	connection_error -> connection_error	1✔
54	end
55	end
56
57	@doc """
58	Checks in the `Kompost.Kompo.Postgres.ConnectionRegistry` for an existing
59	connection defined by the given `id`.
60	"""
61	@spec lookup(id()) :: [
62	{pid, conn_args :: keyword(),
63	allowed_namespaces :: NamespaceAccess.allowed_namespaces()}
64	]
65	def lookup(id) do
66	Registry.lookup(ConnectionRegistry, id)
67	\|> Enum.map(fn {pid, args} ->	37✔
68	{allowed_namespaces, conn_args} = Keyword.pop!(args, :allowed_namespaces)	22✔
69	{pid, conn_args, allowed_namespaces}	22✔
70	end)
71	end
72
73	@doc """
74	Checks if the user connected to the given `conn` has all the privileges
75	required to work with this `Kompo`.
76	"""
77	@spec check_privileges(conn :: Postgrex.conn()) :: :ok \| {:error, binary()}
78	def check_privileges(conn) do
79	with :ok <- Privileges.check_create_role_privilege(conn) do	17✔
80	Privileges.check_create_database_privilege(conn)	15✔
81	end
82	end
83
84	@doc """
85	Disconnects the connection with the given `id` by stopping the referenced
86	`Postgrex` process.
87	"""
88	@spec disconnect(id()) :: :ok
89	def disconnect(id) do
90	case lookup(id) do	7✔
91	[{conn, _, _}] ->
92	# This will also unregister the process at the ConnectionRegistry:
93	DynamicSupervisor.terminate_child(ConnectionSupervisor, conn)	5✔
94	:ok
95
96	[] ->	2✔
97	:ok
98	end
99	end
100	end

mruoss / kompost / bf7b407df487178ba9b793a13ed30727a6359fb6

Source File Press 'n' to go to next uncovered line, 'b' for previous

Source File
Press 'n' to go to next uncovered line, 'b' for previous